Zdefiniuj reguły CMake

bookmark_border Zadbaj o dobrą organizację dzięki kolekcji Zapisuj i kategoryzuj treści zgodnie ze swoimi preferencjami.

Wyświetl kod źródłowy na GitHubie

Autorzy Mason Tran

Współtwórca z SiLabs

System kompilacji CMake korzysta z plików CMakeLists.txt, które definiują cele kompilacji. CMakeLists.txt w korzeniach repozytorium znajduje się u szczytu drzewa kompilacji i jest dobrym miejscem na rozpoczęcie definiowania różnych celów, opcji i makr używanych w procesie kompilacji.

Najpierw należy zdefiniować nazwę projektu i obsługiwane platformy.

W tym przykładzie nazwa projektu to ot-efr32, a wersja to 0.0.1. Definiujemy też zmienną EFR32_PLATFORM_VALUES, która jest listą platform efr32 obsługiwanych przez ot-efr32. Na potrzeby tego przykładu zdefiniowaliśmy kilka platform, ale w przypadku zmiennej _PLATFORM_VALUES wystarczy też jedna platforma.

cmake_minimum_required(VERSION 3.10.2)
project(ot-efr32 VERSION 0.0.1)

set(EFR32_PLATFORM_VALUES
    "efr32mg1"
    "efr32mg12"
    "efr32mg13"
    "efr32mg21"
)

Plik CMakeLists.txt zawiera sprawdzenie, które przerywa kompilacje rozpoczęte na nieobsługiwanych platformach.

set_property(CACHE EFR32_PLATFORM PROPERTY STRINGS ${EFR32_PLATFORM_VALUES})
if(NOT EFR32_PLATFORM IN_LIST EFR32_PLATFORM_VALUES)
    message(FATAL_ERROR "Please select a supported platform: ${EFR32_PLATFORM_VALUES}")
endif()

Kolejną zmienną, którą należy zdefiniować, jest OT_PLATFORM_LIB. Ta zmienna jest używana przez przykładowe aplikacje OpenThread do tworzenia linków do Twojej platformy.

set(OT_PLATFORM_LIB "openthread-${EFR32_PLATFORM}")

Opcje CMake OpenThread

Różne funkcje w OpenThread można włączać, wyłączać i konfigurować, definiując zmienne CMake.

Na platformie ot-efr32 używana jest zewnętrzna biblioteka mbedTLS silabs-mbedtls.

set(OT_BUILTIN_MBEDTLS_MANAGEMENT OFF CACHE BOOL "disable builtin mbedtls management" FORCE)
set(OT_EXTERNAL_MBEDTLS "silabs-mbedtls" CACHE STRING "use silabs mbedtls" FORCE)
set(OT_MBEDTLS ${OT_EXTERNAL_MBEDTLS})

Definiowanie katalogów wyjściowych

Katalog wyjściowy dla różnych plików docelowych można skonfigurować za pomocą podanych niżej zmiennych.

set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)

Dodawanie OpenThread do drzewa kompilacji

Aby uwzględnić w drzewie kompilacji podmoduł openthread:

add_subdirectory(openthread)

Przekazywanie właściwości kompilacji do OpenThread

Ostatnia sekcja tego pliku umożliwia zdefiniowanie właściwości kompilacji (takich jak definicje, opcje i katalogi include), które możesz dodać do drzewa kompilacji openthread i do bibliotek platformy.

Wygodne dodawanie tych definicji jest możliwe dzięki zastosowaniu celu ot-config. Ten cel jest fałszywym celem, który służy wyłącznie do definiowania konfiguracji i jest powiązany z prawie wszystkimi celami CMake w openthread.

# Define config filename macros
target_compile_definitions(ot-config INTERFACE
    OPENTHREAD_CONFIG_FILE="openthread-core-efr32-config.h"
    OPENTHREAD_PROJECT_CORE_CONFIG_FILE="openthread-core-efr32-config.h"
    OPENTHREAD_CORE_CONFIG_PLATFORM_CHECK_FILE="openthread-core-efr32-config-check.h"
)

# Disable -Wshadow and -Wpedantic
target_compile_options(ot-config INTERFACE
    -Wno-shadow
    -Wno-pedantic
)

# Add platform dirs to "include" dirs
target_include_directories(ot-config INTERFACE
    ${PROJECT_SOURCE_DIR}/src/src
    ${PROJECT_SOURCE_DIR}/src/${EFR32_PLATFORM}
    ${PROJECT_SOURCE_DIR}/src/${EFR32_PLATFORM}/crypto
)

Dodawanie podkatalogów do drzewa kompilacji

Po zdefiniowaniu konfiguracji najwyższego poziomu możesz dodać do drzewa kompilacji inne podkatalogi.

W folderze src znajduje się kod źródłowy warstwy abstrakcji platformy. Folder third_party zawiera kod firmy zewnętrznej.

Jeśli chcesz uwzględnić w repozytorium przykładowe aplikacje, utwórz folder examples i dodaj go do drzewa kompilacji.

add_subdirectory(src)
add_subdirectory(third_party)

# Optional
add_subdirectory(examples)

Katalog src

To serce repozytorium, w którym implementowana jest warstwa abstrakcji platformy. Zawiera on też kilka innych wymaganych plików.

src/arm-none-eabi.cmake

To plik łańcucha narzędzi, który definiuje niektóre zmienne używane przez CMake w procesie kompilacji. Na początek warto skopiować wersję tego pliku dla ot-efr32 i zmodyfikować ją tak, aby pasowała do Twojej platformy.

src/CMakeLists.txt

Tutaj definiujesz pliki źródłowe, ścieżki include i flagi kompilatora dla biblioteki platformy. Dobrym przykładem takiego pliku w przypadku repozytorium obsługującego tylko jedną platformę jest ot-cc2538.

Możliwe jest uwzględnienie wielu platform w jednym repozytorium, a jako odniesienie można użyć kilku repozytoriów platform. Zobacz ot-efr32 i ot-nrf528xx.