Définir des règles CMake

<ph type="x-smartling-placeholder"></ph> Consulter le code source sur GitHub

Par <ph type="x-smartling-placeholder"></ph> <ph type="x-smartling-placeholder"></ph> Maçon Tran

Contributeur de SiLabs

Le système de compilation CMake s'appuie sur des fichiers CMakeLists.txt qui définissent les cibles de compilation. Le CMakeLists.txt, à la racine de votre dépôt, se trouve en haut de l'arborescence de compilation. C'est un bon point de départ pour commencer à définir les différentes cibles, options et macros utilisées dans le processus de compilation.

Les toutes premières valeurs à définir sont le nom du projet et les plates-formes compatibles.

Dans cet exemple, nous définissons le nom du projet sur ot-efr32 avec la version 0.0.1. Nous définissons également une variable EFR32_PLATFORM_VALUES, qui est une liste de plates-formes efr32 compatibles avec ot-efr32. Pour les besoins de cet exemple, nous avons défini plusieurs plates-formes, mais il est également acceptable d'avoir une seule plate-forme pour la variable _PLATFORM_VALUES.

cmake_minimum_required(VERSION 3.10.2)
project(ot-efr32 VERSION 0.0.1)

set(EFR32_PLATFORM_VALUES
    "efr32mg1"
    "efr32mg12"
    "efr32mg13"
    "efr32mg21"
)

Le fichier CMakeLists.txt inclut une vérification qui annule les compilations lancées pour les plates-formes non compatibles.

set_property(CACHE EFR32_PLATFORM PROPERTY STRINGS ${EFR32_PLATFORM_VALUES})
if(NOT EFR32_PLATFORM IN_LIST EFR32_PLATFORM_VALUES)
    message(FATAL_ERROR "Please select a supported platform: ${EFR32_PLATFORM_VALUES}")
endif()

La variable suivante qui doit être définie est OT_PLATFORM_LIB. Cette variable est utilisée par les exemples d'applications OpenThread pour se connecter à votre plateforme.

set(OT_PLATFORM_LIB "openthread-${EFR32_PLATFORM}")

Options CMake d'OpenThread

Diverses fonctionnalités d'OpenThread peuvent être activées/désactivées/configurées en définissant des variables CMake.

Sur la plate-forme ot-efr32, une bibliothèque mbedTLS externe silabs-mbedtls est utilisée.

set(OT_BUILTIN_MBEDTLS_MANAGEMENT OFF CACHE BOOL "disable builtin mbedtls management" FORCE)
set(OT_EXTERNAL_MBEDTLS "silabs-mbedtls" CACHE STRING "use silabs mbedtls" FORCE)
set(OT_MBEDTLS ${OT_EXTERNAL_MBEDTLS})

Définir les répertoires de sortie

Le répertoire de sortie des différents fichiers cibles peut être configuré à l'aide des variables ci-dessous.

set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)

Ajouter OpenThread à l'arborescence de compilation

Pour inclure le sous-module openthread dans l'arborescence de compilation:

add_subdirectory(openthread)

Transmettre les propriétés de compilation à OpenThread

La dernière section de ce fichier vous permet de définir des propriétés de compilation (telles que des définitions, des options et des répertoires d'inclusion) que vous pouvez ajouter à l'arborescence de compilation openthread et aux bibliothèques de votre plate-forme.

Un moyen pratique d'ajouter ces définitions consiste à utiliser la cible ot-config. Cette cible est une cible fictive qui sert uniquement à définir la configuration. Elle est associée à presque toutes les cibles CMake dans openthread.

# Define config filename macros
target_compile_definitions(ot-config INTERFACE
    OPENTHREAD_CONFIG_FILE="openthread-core-efr32-config.h"
    OPENTHREAD_PROJECT_CORE_CONFIG_FILE="openthread-core-efr32-config.h"
    OPENTHREAD_CORE_CONFIG_PLATFORM_CHECK_FILE="openthread-core-efr32-config-check.h"
)

# Disable -Wshadow and -Wpedantic
target_compile_options(ot-config INTERFACE
    -Wno-shadow
    -Wno-pedantic
)

# Add platform dirs to "include" dirs
target_include_directories(ot-config INTERFACE
    ${PROJECT_SOURCE_DIR}/src/src
    ${PROJECT_SOURCE_DIR}/src/${EFR32_PLATFORM}
    ${PROJECT_SOURCE_DIR}/src/${EFR32_PLATFORM}/crypto
)

Ajouter des sous-répertoires à l'arborescence de compilation

Maintenant que la configuration de premier niveau est définie, vous pouvez ajouter d'autres sous-répertoires à l'arborescence de compilation.

Le dossier src contient le code source de la couche d'abstraction de plate-forme. Le dossier third_party contient du code tiers.

Si vous souhaitez inclure des exemples d'applications dans le dépôt, créez un dossier examples et ajoutez-le également à l'arborescence de compilation.

add_subdirectory(src)
add_subdirectory(third_party)

# Optional
add_subdirectory(examples)

Le répertoire src

C'est le cœur du dépôt, et c'est là que la couche d'abstraction de la plate-forme est implémentée. Il contient également quelques autres fichiers obligatoires.

src/arm-none-eabi.cmake

Il s'agit d'un fichier de chaîne d'outils qui définit certaines variables utilisées par CMake dans le processus de compilation. Un bon point de départ consiste à copier la version ot-efr32 de ce fichier et à la modifier pour l'adapter à votre plate-forme.

src/CMakeLists.txt

C'est ici que vous définissez les fichiers sources, ainsi que les chemins d'accès et les indicateurs de compilation pour votre bibliothèque de plate-forme. ot-cc2538 est un bon exemple de ce fichier pour un dépôt n'acceptant qu'une seule plate-forme.

La prise en charge de plusieurs plates-formes dans un même dépôt est possible, et plusieurs dépôts de plate-forme peuvent être utilisés comme référence. Voir ot-efr32 et ot-nrf528xx.