Google 致力于为黑人社区推动种族平等。查看具体行动

定义 CMake 规则

使用集合让一切井井有条 根据您的偏好保存内容并对其进行分类。

在 GitHub 上查看源代码

CMake 构建系统依赖于定义构建目标的 CMakeLists.txt 文件。代码库根目录的 CMakeLists.txt 是 build 树的顶部,是开始定义构建流程中使用的各种目标、选项和宏的理想位置。

最先定义的值为项目名称和支持的平台。

在此示例中,我们将项目名称设置为 ot-efr32,版本为 0.0.1。我们还定义了一个变量 EFR32_PLATFORM_VALUES,即 ot-efr32 支持的 efr32 平台的列表。在本示例中,我们定义了多个平台,不过为 _PLATFORM_VALUES 变量提供一个平台也是可以的。

cmake_minimum_required(VERSION 3.10.2)
project(ot-efr32 VERSION 0.0.1)

set(EFR32_PLATFORM_VALUES
    "efr32mg1"
    "efr32mg12"
    "efr32mg13"
    "efr32mg21"
)

CMakeLists.txt 文件包含用于取消针对不受支持的平台启动的 build 的检查。

set_property(CACHE EFR32_PLATFORM PROPERTY STRINGS ${EFR32_PLATFORM_VALUES})
if(NOT EFR32_PLATFORM IN_LIST EFR32_PLATFORM_VALUES)
    message(FATAL_ERROR "Please select a supported platform: ${EFR32_PLATFORM_VALUES}")
endif()

需要定义的下一个变量是 OT_PLATFORM_LIB。OpenThread 示例应用使用该变量链接到您的平台。

set(OT_PLATFORM_LIB "openthread-${EFR32_PLATFORM}")

OpenThread CMake 选项

您可以通过定义 CMake 变量来启用/停用/配置 OpenThread 中的各种功能。

ot-efr32 平台上,使用外部 mbedTLS 库 silabs-mbedtls

set(OT_BUILTIN_MBEDTLS_MANAGEMENT OFF CACHE BOOL "disable builtin mbedtls management" FORCE)
set(OT_EXTERNAL_MBEDTLS "silabs-mbedtls" CACHE STRING "use silabs mbedtls" FORCE)
set(OT_MBEDTLS ${OT_EXTERNAL_MBEDTLS})

定义输出目录

可以使用以下变量配置不同目标文件的输出目录。

set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)

将 OpenThread 添加到 build 树

如需在 build 树中添加 openthread 子模块,请执行以下操作:

add_subdirectory(openthread)

将构建属性传递给 OpenThread

此文件的最后一部分允许您定义构建属性(例如定义、选项和包含目录),您可能需要将这些属性添加到 openthread 构建树以及您的平台库中。

添加这些定义的便捷方式是使用 ot-config 目标。此目标是一个虚构的目标,仅用于定义配置,并由 openthread 中的几乎所有 CMake 目标关联。

# Define config filename macros
target_compile_definitions(ot-config INTERFACE
    OPENTHREAD_CONFIG_FILE="openthread-core-efr32-config.h"
    OPENTHREAD_PROJECT_CORE_CONFIG_FILE="openthread-core-efr32-config.h"
    OPENTHREAD_CORE_CONFIG_PLATFORM_CHECK_FILE="openthread-core-efr32-config-check.h"
)

# Disable -Wshadow and -Wpedantic
target_compile_options(ot-config INTERFACE
    -Wno-shadow
    -Wno-pedantic
)

# Add platform dirs to "include" dirs
target_include_directories(ot-config INTERFACE
    ${PROJECT_SOURCE_DIR}/src/src
    ${PROJECT_SOURCE_DIR}/src/${EFR32_PLATFORM}
    ${PROJECT_SOURCE_DIR}/src/${EFR32_PLATFORM}/crypto
)

将子目录添加到 build 树中

定义顶级配置后,接下来便可向 build 树添加其他子目录。

src 文件夹是平台抽象层源代码所在的位置。third_party 文件夹包含任何第三方代码。

如果您想要在代码库中添加示例应用,请创建一个 examples 文件夹并将其添加到 build 树中。

add_subdirectory(src)
add_subdirectory(third_party)

# Optional
add_subdirectory(examples)

src 目录

这是存储库的核心,用于实现平台抽象层。它还包含一些其他必需的文件。

src/arm-none-eabi.cmake

这是一个工具链文件,用于定义 CMake 构建过程中使用的一些变量。您不妨从此文件的 ot-efr32 版本开始,然后根据您的平台对其进行修改。

src/CMakeLists.txt

您可以在此处定义平台库的源文件、包含路径和编译器标记。对于仅支持单个平台的代码库,此文件是一个很好的示例,它来自 ot-cc2538

可以在单个代码库中支持多个平台,并且可以将多个平台代码库用作参考。请参阅 ot-efr32ot-nrf528xx