Определение правил CMake

Посмотреть исходный код на GitHub

Мейсон Тран _

Участник SiLabs

Система сборки CMake использует файлы CMakeLists.txt , которые определяют цели сборки. CMakeLists.txt в корне вашего репозитория является вершиной дерева сборки и является хорошим местом для начала определения различных целей, параметров и макросов, используемых в процессе сборки.

Самыми первыми значениями, которые необходимо определить, являются имя проекта и поддерживаемые платформы.

В этом примере мы устанавливаем имя проекта ot-efr32 с версией 0.0.1 . Мы также определяем переменную EFR32_PLATFORM_VALUES , которая представляет собой список платформ efr32 , поддерживаемых ot-efr32 . Ради этого примера мы определили несколько платформ, но иметь одну платформу для переменной _PLATFORM_VALUES нормально.

cmake_minimum_required(VERSION 3.10.2)
project(ot-efr32 VERSION 0.0.1)

set(EFR32_PLATFORM_VALUES
    "efr32mg1"
    "efr32mg12"
    "efr32mg13"
    "efr32mg21"
)

Файл CMakeLists.txt включает проверку, которая прерывает сборки, запущенные для неподдерживаемых платформ.

set_property(CACHE EFR32_PLATFORM PROPERTY STRINGS ${EFR32_PLATFORM_VALUES})
if(NOT EFR32_PLATFORM IN_LIST EFR32_PLATFORM_VALUES)
    message(FATAL_ERROR "Please select a supported platform: ${EFR32_PLATFORM_VALUES}")
endif()

Следующая переменная, которую необходимо определить, это OT_PLATFORM_LIB . Эта переменная используется примерами приложений OpenThread для связи с вашей платформой.

set(OT_PLATFORM_LIB "openthread-${EFR32_PLATFORM}")

Параметры OpenThread CMake

Различные функции в OpenThread могут быть включены/отключены/настроены путем определения переменных CMake.

На платформе ot-efr32 используется внешняя библиотека silabs-mbedtls .

set(OT_BUILTIN_MBEDTLS_MANAGEMENT OFF CACHE BOOL "disable builtin mbedtls management" FORCE)
set(OT_EXTERNAL_MBEDTLS "silabs-mbedtls" CACHE STRING "use silabs mbedtls" FORCE)
set(OT_MBEDTLS ${OT_EXTERNAL_MBEDTLS})

Определить выходные каталоги

Выходной каталог для различных целевых файлов можно настроить с помощью переменных ниже.

set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)

Добавьте OpenThread в дерево сборки

Чтобы включить подмодуль openthread в дерево сборки:

add_subdirectory(openthread)

Передать свойства сборки в OpenThread

Последний раздел этого файла позволяет вам определить свойства сборки (такие как определения, параметры и включаемые каталоги), которые вы можете добавить в дерево сборки openthread и в библиотеки вашей платформы.

Удобный способ добавить эти определения — использовать цель ot-config . Эта цель является фальшивой целью, которая используется исключительно для определения конфигурации и связана почти со всеми целями CMake в openthread .

# Define config filename macros
target_compile_definitions(ot-config INTERFACE
    OPENTHREAD_CONFIG_FILE="openthread-core-efr32-config.h"
    OPENTHREAD_PROJECT_CORE_CONFIG_FILE="openthread-core-efr32-config.h"
    OPENTHREAD_CORE_CONFIG_PLATFORM_CHECK_FILE="openthread-core-efr32-config-check.h"
)

# Disable -Wshadow and -Wpedantic
target_compile_options(ot-config INTERFACE
    -Wno-shadow
    -Wno-pedantic
)

# Add platform dirs to "include" dirs
target_include_directories(ot-config INTERFACE
    ${PROJECT_SOURCE_DIR}/src/src
    ${PROJECT_SOURCE_DIR}/src/${EFR32_PLATFORM}
    ${PROJECT_SOURCE_DIR}/src/${EFR32_PLATFORM}/crypto
)

Добавьте подкаталоги в дерево сборки

Теперь, когда конфигурация верхнего уровня определена, пришло время добавить другие подкаталоги в дерево сборки.

В папке src находится исходный код слоя абстракции платформы. Папка third_party содержит любой сторонний код.

Если вы хотите включить примеры приложений в репозиторий, создайте папку examples и также добавьте ее в дерево сборки.

add_subdirectory(src)
add_subdirectory(third_party)

# Optional
add_subdirectory(examples)

Каталог src

Это сердце репозитория, где реализуется уровень абстракции платформы. Он также содержит несколько других необходимых файлов.

src/arm-none-eabi.cmake

Это файл цепочки инструментов, который определяет некоторые переменные, которые CMake использует в процессе сборки. Хорошей отправной точкой было бы скопировать версию этого файла ot-efr32 и изменить ее в соответствии с вашей платформой.

src/CMakeLists.txt

Здесь вы определяете исходные файлы, включаете пути и флаги компилятора для вашей библиотеки платформы. Хороший пример этого файла для репозитория, который поддерживает только одну платформу, взят из ot-cc2538 .

Возможна поддержка нескольких платформ в одном репозитории, и несколько репозиториев платформ могут использоваться в качестве эталона. См. ot-efr32 и ot-nrf528xx .