הגדרה של כללי CMake

הצגת המקור ב-GitHub

מאת Mason Tran

תורם מ-SiLabs

מערכת ה-build של CMake מסתמכת על קובצי CMakeLists.txt שמגדירים יעדי build. הקובץ CMakeLists.txt ברמה הבסיסית של המאגר הוא החלק העליון של עץ ה-build, והוא מקום טוב להתחיל להגדיר את היעדים, האפשרויות והמאקרוים השונים שמשמשים בתהליך ה-build.

הערכים הראשונים שצריך להגדיר הם שם הפרויקט והפלטפורמות הנתמכות.

בדוגמה הזו, הגדרנו את שם הפרויקט כ-ot-efr32 עם גרסה 0.0.1. אנחנו גם מגדירים את המשתנה EFR32_PLATFORM_VALUES, שהוא רשימה של פלטפורמות efr32 שנתמכות על ידי ot-efr32. בדוגמה הזו הגדרנו כמה פלטפורמות, אבל אפשר להגדיר גם פלטפורמה אחת למשתנה _PLATFORM_VALUES.

cmake_minimum_required(VERSION 3.10.2)
project(ot-efr32 VERSION 0.0.1)

set(EFR32_PLATFORM_VALUES
    "efr32mg1"
    "efr32mg12"
    "efr32mg13"
    "efr32mg21"
)

הקובץ CMakeLists.txt כולל בדיקה שמבטלת גרסאות build שהופעלו בפלטפורמות שלא נתמכות.

set_property(CACHE EFR32_PLATFORM PROPERTY STRINGS ${EFR32_PLATFORM_VALUES})
if(NOT EFR32_PLATFORM IN_LIST EFR32_PLATFORM_VALUES)
    message(FATAL_ERROR "Please select a supported platform: ${EFR32_PLATFORM_VALUES}")
endif()

המשתנה הבא שצריך להגדיר הוא OT_PLATFORM_LIB. אפליקציות הדוגמה של OpenThread משתמשות במשתנה הזה כדי לקשר לפלטפורמה שלכם.

set(OT_PLATFORM_LIB "openthread-${EFR32_PLATFORM}")

אפשרויות CMake ב-OpenThread

אפשר להגדיר, להפעיל או להשבית תכונות שונות ב-OpenThread על ידי הגדרת משתני CMake.

בפלטפורמה ot-efr32 נעשה שימוש בספרייה חיצונית של mbedTLS‏ silabs-mbedtls.

set(OT_BUILTIN_MBEDTLS_MANAGEMENT OFF CACHE BOOL "disable builtin mbedtls management" FORCE)
set(OT_EXTERNAL_MBEDTLS "silabs-mbedtls" CACHE STRING "use silabs mbedtls" FORCE)
set(OT_MBEDTLS ${OT_EXTERNAL_MBEDTLS})

הגדרת ספריות פלט

אפשר להגדיר את ספריית הפלט של קובצי יעד שונים באמצעות המשתנים הבאים.

set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)

הוספת OpenThread לעץ ה-build

כדי לכלול את תת-המודול openthread בעץ ה-build:

add_subdirectory(openthread)

העברת מאפייני build ל-OpenThread

בקטע האחרון של הקובץ הזה אפשר להגדיר מאפייני build (כמו הגדרות, אפשרויות וספריות include) שרוצים להוסיף לעץ ה-build של openthread ולספריות הפלטפורמה.

דרך נוחה להוסיף את ההגדרות האלה היא באמצעות היעד ot-config. היעד הזה הוא יעד מזויף שמשמש אך ורק למטרת הגדרת ההגדרות, וכמעט כל יעדי CMake ב-openthread מקושרים אליו.

# Define config filename macros
target_compile_definitions(ot-config INTERFACE
    OPENTHREAD_CONFIG_FILE="openthread-core-efr32-config.h"
    OPENTHREAD_PROJECT_CORE_CONFIG_FILE="openthread-core-efr32-config.h"
    OPENTHREAD_CORE_CONFIG_PLATFORM_CHECK_FILE="openthread-core-efr32-config-check.h"
)

# Disable -Wshadow and -Wpedantic
target_compile_options(ot-config INTERFACE
    -Wno-shadow
    -Wno-pedantic
)

# Add platform dirs to "include" dirs
target_include_directories(ot-config INTERFACE
    ${PROJECT_SOURCE_DIR}/src/src
    ${PROJECT_SOURCE_DIR}/src/${EFR32_PLATFORM}
    ${PROJECT_SOURCE_DIR}/src/${EFR32_PLATFORM}/crypto
)

הוספת תיקיות משנה לעץ ה-build

עכשיו, אחרי שהגדרתם את ההגדרות ברמה העליונה, הגיע הזמן להוסיף ספריות משנה אחרות לעץ ה-build.

התיקייה src היא המיקום של קוד המקור של שכבת הפלטפורמה לניתוח נתונים. התיקייה third_party מכילה קוד של צד שלישי.

אם רוצים לכלול אפליקציות לדוגמה במאגר, יוצרים תיקייה examples ומוסיפים אותה גם לעץ ה-build.

add_subdirectory(src)
add_subdirectory(third_party)

# Optional
add_subdirectory(examples)

הספרייה src

זהו הלב של המאגר, והמקום שבו שכבת הפלטפורמה המופשטת מיושמת. הוא מכיל גם כמה קבצים נדרשים אחרים.

src/arm-none-eabi.cmake

זהו קובץ של כלי פיתוח שמגדיר משתנים מסוימים שבהם CMake משתמש בתהליך ה-build. נקודת התחלה טובה היא להעתיק את גרסה ot-efr32 של הקובץ הזה ולשנות אותה בהתאם לפלטפורמה שלכם.

src/CMakeLists.txt

כאן מגדירים את קובצי המקור, נתיבי ההכללה ודגלי המהדר של ספריית הפלטפורמה. דוגמה טובה לקובץ כזה במאגר שתומך רק בפלטפורמה אחת היא ot-cc2538.

אפשר לתמוך במספר פלטפורמות במאגר אחד, וניתן להשתמש בכמה מאגרים של פלטפורמות כמקור מידע. ראו ot-efr32 ו-ot-nrf528xx.