Le système de compilation CMake s'appuie sur des fichiers CMakeLists.txt qui définissent des cibles de compilation. Le CMakeLists.txt à la racine de votre dépôt se trouve en haut de l'arborescence de compilation. Il constitue un bon point de départ pour définir les différentes cibles, options et macros utilisées dans le processus de compilation.
Les premières valeurs à définir sont le nom du projet et les plates-formes compatibles.
Dans cet exemple, nous définissons le nom du projet sur ot-efr32 avec une version de 0.0.1. Nous définissons également une variable EFR32_PLATFORM_VALUES, qui est une liste des plates-formes efr32 compatibles avec ot-efr32. Pour cet exemple, nous avons défini plusieurs plates-formes, mais une seule plate-forme pour la variable _PLATFORM_VALUES est également acceptable.
cmake_minimum_required(VERSION 3.10.2)
project(ot-efr32 VERSION 0.0.1)
set(EFR32_PLATFORM_VALUES
"efr32mg1"
"efr32mg12"
"efr32mg13"
"efr32mg21"
)
Le fichier CMakeLists.txt inclut une vérification qui interrompt les builds lancés pour les plates-formes non compatibles.
set_property(CACHE EFR32_PLATFORM PROPERTY STRINGS ${EFR32_PLATFORM_VALUES})
if(NOT EFR32_PLATFORM IN_LIST EFR32_PLATFORM_VALUES)
message(FATAL_ERROR "Please select a supported platform: ${EFR32_PLATFORM_VALUES}")
endif()
La variable suivante à définir est OT_PLATFORM_LIB. Cette variable est utilisée par les exemples d'applications OpenThread pour établir un lien avec votre plate-forme.
set(OT_PLATFORM_LIB "openthread-${EFR32_PLATFORM}")
Options CMake OpenThread
Vous pouvez activer/désactiver/configurer différentes fonctionnalités d'OpenThread en définissant des variables CMake.
Sur la plate-forme ot-efr32, une bibliothèque mbedTLS externe silabs-mbedtls est utilisée.
set(OT_BUILTIN_MBEDTLS_MANAGEMENT OFF CACHE BOOL "disable builtin mbedtls management" FORCE)
set(OT_EXTERNAL_MBEDTLS "silabs-mbedtls" CACHE STRING "use silabs mbedtls" FORCE)
set(OT_MBEDTLS ${OT_EXTERNAL_MBEDTLS})
Définir des répertoires de sortie
Le répertoire de sortie des différents fichiers cibles peut être configuré à l'aide des variables ci-dessous.
set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
Ajouter OpenThread à l'arborescence de compilation
Pour inclure le sous-module openthread dans l'arborescence de compilation:
add_subdirectory(openthread)
Transmettre des propriétés de compilation à OpenThread
La dernière section de ce fichier vous permet de définir des propriétés de compilation (telles que des définitions, des options et des répertoires d'inclusion) que vous pouvez ajouter à l'arborescence de compilation openthread et à vos bibliothèques de plate-forme.
Un moyen pratique d'ajouter ces définitions consiste à utiliser la cible ot-config. Cette cible est une cible factice qui n'est utilisée que pour définir la configuration et est liée à presque toutes les cibles CMake dans openthread.
# Define config filename macros
target_compile_definitions(ot-config INTERFACE
OPENTHREAD_CONFIG_FILE="openthread-core-efr32-config.h"
OPENTHREAD_PROJECT_CORE_CONFIG_FILE="openthread-core-efr32-config.h"
OPENTHREAD_CORE_CONFIG_PLATFORM_CHECK_FILE="openthread-core-efr32-config-check.h"
)
# Disable -Wshadow and -Wpedantic
target_compile_options(ot-config INTERFACE
-Wno-shadow
-Wno-pedantic
)
# Add platform dirs to "include" dirs
target_include_directories(ot-config INTERFACE
${PROJECT_SOURCE_DIR}/src/src
${PROJECT_SOURCE_DIR}/src/${EFR32_PLATFORM}
${PROJECT_SOURCE_DIR}/src/${EFR32_PLATFORM}/crypto
)
Ajouter des sous-répertoires à l'arborescence de compilation
Maintenant que la configuration de premier niveau est définie, il est temps d'ajouter d'autres sous-répertoires à l'arborescence de compilation.
Le code source de la couche d'abstraction de la plate-forme se trouve dans le dossier src. Le dossier third_party contient tout code tiers.
Si vous souhaitez inclure des exemples d'applications dans le dépôt, créez un dossier examples et ajoutez-le également à l'arborescence de compilation.
add_subdirectory(src) add_subdirectory(third_party) # Optional add_subdirectory(examples)
Le répertoire src
Il s'agit du cœur du dépôt, où la couche d'abstraction de la plate-forme est implémentée. Il contient également quelques autres fichiers requis.
src/arm-none-eabi.cmake
Il s'agit d'un fichier de chaîne d'outils qui définit certaines variables utilisées par CMake dans le processus de compilation. Un bon point de départ consiste à copier la version ot-efr32 de ce fichier et à la modifier pour l'adapter à votre plate-forme.
src/CMakeLists.txt
C'est là que vous définissez les fichiers sources, les chemins d'accès et les options de compilation de votre bibliothèque de plate-forme. ot-cc2538 est un bon exemple de fichier pour un dépôt qui n'est compatible qu'avec une seule plate-forme.
Il est possible de prendre en charge plusieurs plates-formes dans un même dépôt, et plusieurs dépôts de plates-formes peuvent être utilisés comme référence. Voir ot-efr32 et ot-nrf528xx.