Das CMake-Buildsystem verwendet CMakeLists.txt-Dateien, in denen Buildziele definiert werden. Das CMakeLists.txt im Stammverzeichnis Ihres Repositories ist der Anfang des Build-Baums und ein guter Ausgangspunkt, um die verschiedenen Ziele, Optionen und Makros zu definieren, die im Build-Prozess verwendet werden.
Als Erstes müssen Sie den Projektnamen und die unterstützten Plattformen definieren.
In diesem Beispiel haben wir den Projektnamen auf ot-efr32 mit der Version 0.0.1 festgelegt. Außerdem definieren wir die Variable EFR32_PLATFORM_VALUES, eine Liste der efr32-Plattformen, die von ot-efr32 unterstützt werden. In diesem Beispiel haben wir mehrere Plattformen definiert. Es ist aber auch in Ordnung, wenn Sie nur eine Plattform für die Variable _PLATFORM_VALUES angeben.
cmake_minimum_required(VERSION 3.10.2)
project(ot-efr32 VERSION 0.0.1)
set(EFR32_PLATFORM_VALUES
"efr32mg1"
"efr32mg12"
"efr32mg13"
"efr32mg21"
)
Die Datei CMakeLists.txt enthält eine Prüfung, die Builds abbricht, die für nicht unterstützte Plattformen gestartet wurden.
set_property(CACHE EFR32_PLATFORM PROPERTY STRINGS ${EFR32_PLATFORM_VALUES})
if(NOT EFR32_PLATFORM IN_LIST EFR32_PLATFORM_VALUES)
message(FATAL_ERROR "Please select a supported platform: ${EFR32_PLATFORM_VALUES}")
endif()
Die nächste Variable, die definiert werden muss, ist OT_PLATFORM_LIB. Diese Variable wird von den OpenThread-Beispielanwendungen verwendet, um eine Verknüpfung mit Ihrer Plattform herzustellen.
set(OT_PLATFORM_LIB "openthread-${EFR32_PLATFORM}")
OpenThread-CMake-Optionen
Durch Definieren von CMake-Variablen können verschiedene Funktionen in OpenThread aktiviert, deaktiviert oder konfiguriert werden.
Auf der ot-efr32-Plattform wird eine externe mbedTLS-Bibliothek silabs-mbedtls verwendet.
set(OT_BUILTIN_MBEDTLS_MANAGEMENT OFF CACHE BOOL "disable builtin mbedtls management" FORCE)
set(OT_EXTERNAL_MBEDTLS "silabs-mbedtls" CACHE STRING "use silabs mbedtls" FORCE)
set(OT_MBEDTLS ${OT_EXTERNAL_MBEDTLS})
Ausgabeverzeichnisse definieren
Das Ausgabeverzeichnis für verschiedene Zieldateien kann mit den folgenden Variablen konfiguriert werden.
set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
OpenThread zum Build-Baum hinzufügen
So nehmen Sie das openthread-Untermodul in den Build-Baum auf:
add_subdirectory(openthread)
Build-Eigenschaften an OpenThread übergeben
Im letzten Abschnitt dieser Datei können Sie Build-Eigenschaften wie Definitionen, Optionen und Include-Verzeichnisse definieren, die Sie dem openthread-Build-Baum und Ihren Plattformbibliotheken hinzufügen möchten.
Eine praktische Möglichkeit, diese Definitionen hinzuzufügen, ist das Ziel ot-config. Dieses Ziel ist ein Pseudoziel, das ausschließlich zum Definieren der Konfiguration verwendet wird und mit dem fast alle CMake-Ziele in openthread verknüpft sind.
# Define config filename macros
target_compile_definitions(ot-config INTERFACE
OPENTHREAD_CONFIG_FILE="openthread-core-efr32-config.h"
OPENTHREAD_PROJECT_CORE_CONFIG_FILE="openthread-core-efr32-config.h"
OPENTHREAD_CORE_CONFIG_PLATFORM_CHECK_FILE="openthread-core-efr32-config-check.h"
)
# Disable -Wshadow and -Wpedantic
target_compile_options(ot-config INTERFACE
-Wno-shadow
-Wno-pedantic
)
# Add platform dirs to "include" dirs
target_include_directories(ot-config INTERFACE
${PROJECT_SOURCE_DIR}/src/src
${PROJECT_SOURCE_DIR}/src/${EFR32_PLATFORM}
${PROJECT_SOURCE_DIR}/src/${EFR32_PLATFORM}/crypto
)
Unterverzeichnisse zum Build-Baum hinzufügen
Nachdem die Konfiguration der obersten Ebene definiert ist, können Sie dem Build-Baum weitere Unterverzeichnisse hinzufügen.
Im Ordner src befindet sich der Quellcode der Plattformabstraktionsschicht. Der Ordner third_party enthält Drittanbietercode.
Wenn Sie Beispielanwendungen in das Repository aufnehmen möchten, erstellen Sie einen Ordner examples und fügen Sie ihn dem Build-Baum hinzu.
add_subdirectory(src) add_subdirectory(third_party) # Optional add_subdirectory(examples)
Verzeichnis src
Dies ist das Herzstück des Repositorys und hier wird die Plattformabstraktionsschicht implementiert. Außerdem enthält sie einige weitere erforderliche Dateien.
src/arm-none-eabi.cmake
Dies ist eine Toolchain-Datei, in der einige Variablen definiert sind, die CMake im Build-Prozess verwendet. Ein guter Ausgangspunkt wäre, die ot-efr32-Version dieser Datei zu kopieren und an deine Plattform anzupassen.
src/CMakeLists.txt
Hier definieren Sie die Quelldateien, Include-Pfade und Compiler-Flags für Ihre Plattformbibliothek. Ein gutes Beispiel für diese Datei für ein Repository, das nur eine einzige Plattform unterstützt, ist ot-cc2538.
Die Unterstützung mehrerer Plattformen in einem einzigen Repository ist möglich und mehrere Plattform-Repositories können als Referenz verwendet werden. Weitere Informationen finden Sie unter ot-efr32 und ot-nrf528xx.