System kompilacji CMake opiera się na plikach CMakeLists.txt, które definiują cele kompilacji. Element CMakeLists.txt w katalogu głównym repozytorium to górny róg drzewa kompilacji. To dobry punkt wyjścia do definiowania różnych celów, opcji i makr używanych w procesie kompilacji.
Pierwsze wartości do zdefiniowania to nazwa projektu i obsługiwane platformy.
W tym przykładzie ustawiliśmy nazwę projektu na ot-efr32 z wersją 0.0.1. Definiujemy również zmienną EFR32_PLATFORM_VALUES, która jest listą platform efr32 obsługiwanych przez ot-efr32. Na potrzeby tego przykładu zdefiniowaliśmy wiele platform, ale zastosowanie jednej platformy w przypadku zmiennej _PLATFORM_VALUES też jest dopuszczalne.
cmake_minimum_required(VERSION 3.10.2)
project(ot-efr32 VERSION 0.0.1)
set(EFR32_PLATFORM_VALUES
"efr32mg1"
"efr32mg12"
"efr32mg13"
"efr32mg21"
)
Plik CMakeLists.txt zawiera informacje o sprawdzaniu, czy kompilacje uruchomione na nieobsługiwanych platformach są przerywane.
set_property(CACHE EFR32_PLATFORM PROPERTY STRINGS ${EFR32_PLATFORM_VALUES})
if(NOT EFR32_PLATFORM IN_LIST EFR32_PLATFORM_VALUES)
message(FATAL_ERROR "Please select a supported platform: ${EFR32_PLATFORM_VALUES}")
endif()
Kolejna zmienna, którą należy zdefiniować, to OT_PLATFORM_LIB. Ta zmienna jest używana przez przykładowe aplikacje OpenThread do łączenia z Twoją platformą.
set(OT_PLATFORM_LIB "openthread-${EFR32_PLATFORM}")
Opcje OpenThread CMake
Różne funkcje OpenThread można włączać, wyłączać i konfigurować przez zdefiniowanie zmiennych CMake.
Na platformie ot-efr32 używana jest zewnętrzna biblioteka mbedTLS silabs-mbedtls.
set(OT_BUILTIN_MBEDTLS_MANAGEMENT OFF CACHE BOOL "disable builtin mbedtls management" FORCE)
set(OT_EXTERNAL_MBEDTLS "silabs-mbedtls" CACHE STRING "use silabs mbedtls" FORCE)
set(OT_MBEDTLS ${OT_EXTERNAL_MBEDTLS})
Zdefiniuj katalogi wyjściowe
Katalog wyjściowy dla różnych plików docelowych można skonfigurować za pomocą poniższych zmiennych.
set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
Dodawanie OpenThread do drzewa kompilacji
Aby uwzględnić moduł podrzędny openthread w drzewie kompilacji:
add_subdirectory(openthread)
Przekazywanie właściwości kompilacji do OpenThread
W ostatniej sekcji tego pliku możesz zdefiniować właściwości kompilacji (takie jak definicje, opcje czy uwzględnianie katalogów), które warto dodać do drzewa kompilacji openthread i do bibliotek platformy.
Wygodny sposób dodawania tych definicji to użycie celu ot-config. Ten cel to fałszywy cel, który jest używany wyłącznie do definiowania konfiguracji i jest powiązany z prawie wszystkimi celami CMake w openthread.
# Define config filename macros
target_compile_definitions(ot-config INTERFACE
OPENTHREAD_CONFIG_FILE="openthread-core-efr32-config.h"
OPENTHREAD_PROJECT_CORE_CONFIG_FILE="openthread-core-efr32-config.h"
OPENTHREAD_CORE_CONFIG_PLATFORM_CHECK_FILE="openthread-core-efr32-config-check.h"
)
# Disable -Wshadow and -Wpedantic
target_compile_options(ot-config INTERFACE
-Wno-shadow
-Wno-pedantic
)
# Add platform dirs to "include" dirs
target_include_directories(ot-config INTERFACE
${PROJECT_SOURCE_DIR}/src/src
${PROJECT_SOURCE_DIR}/src/${EFR32_PLATFORM}
${PROJECT_SOURCE_DIR}/src/${EFR32_PLATFORM}/crypto
)
Dodaj podkatalogi do drzewa kompilacji
Po zdefiniowaniu konfiguracji najwyższego poziomu możesz dodać do drzewa kompilacji inne podkatalogi.
Folder src zawiera kod źródłowy warstwy abstrakcji platformy. Folder third_party zawiera kod innej firmy.
Jeśli chcesz uwzględnić w repozytorium przykładowe aplikacje, utwórz folder examples i dodaj go do drzewa kompilacji.
add_subdirectory(src) add_subdirectory(third_party) # Optional add_subdirectory(examples)
Katalog src
To serce repozytorium i wdrożona w nim warstwa abstrakcji platformy. Zawiera też kilka innych wymaganych plików.
src/arm-none-eabi.cmake
Jest to plik łańcucha narzędzi, który definiuje niektóre zmienne używane przez CMake w procesie kompilacji. Dobrym punktem wyjścia jest skopiowanie wersji ot-efr32 tego pliku i zmodyfikowanie go, tak aby pasował do Twojej platformy.
src/CMakeLists.txt
Tutaj definiujesz pliki źródłowe, dodajesz ścieżki i flagi kompilatora do biblioteki platformy. Dobrym przykładem tego pliku w przypadku repozytorium obsługującego tylko jedną platformę jest ot-cc2538.
W jednym repozytorium można korzystać z wielu platform. Jako punktu odniesienia można też używać kilku repozytoriów platform. Zobacz ot-efr32 i ot-nrf528xx.