<ph type="x-smartling-placeholder"></ph>
在 GitHub 上查看源代码
CMake 构建系统依赖于用于定义构建目标的 CMakeLists.txt 文件。代码库根目录下的 CMakeLists.txt 是 build 树的顶部，非常适合用来开始定义构建流程中使用的各种目标、选项和宏。
首先要定义的值是项目名称和支持的平台。
在此示例中，我们将项目名称设置为 ot-efr32，版本为 0.0.1。我们还定义了一个变量 EFR32_PLATFORM_VALUES，它是 ot-efr32 支持的 efr32 平台的列表。在本示例中，我们定义了多个平台，但也为 _PLATFORM_VALUES 变量指定一个平台。
cmake_minimum_required(VERSION 3.10.2)
project(ot-efr32 VERSION 0.0.1)
set(EFR32_PLATFORM_VALUES
"efr32mg1"
"efr32mg12"
"efr32mg13"
"efr32mg21"
)
CMakeLists.txt 文件包含一项检查，用于中止针对不受支持的平台启动的 build。
set_property(CACHE EFR32_PLATFORM PROPERTY STRINGS ${EFR32_PLATFORM_VALUES})
if(NOT EFR32_PLATFORM IN_LIST EFR32_PLATFORM_VALUES)
message(FATAL_ERROR "Please select a supported platform: ${EFR32_PLATFORM_VALUES}")
endif()
下一个需要定义的变量是 OT_PLATFORM_LIB。OpenThread 示例应用使用此变量链接到您的平台。
set(OT_PLATFORM_LIB "openthread-${EFR32_PLATFORM}")
OpenThread CMake 选项
您可以通过定义 CMake 变量来启用/停用/配置 OpenThread 中的各种功能。
在 ot-efr32 平台上，使用外部 mbedTLS 库 silabs-mbedtls。
set(OT_BUILTIN_MBEDTLS_MANAGEMENT OFF CACHE BOOL "disable builtin mbedtls management" FORCE)
set(OT_EXTERNAL_MBEDTLS "silabs-mbedtls" CACHE STRING "use silabs mbedtls" FORCE)
set(OT_MBEDTLS ${OT_EXTERNAL_MBEDTLS})
定义输出目录
您可以使用以下变量配置不同目标文件的输出目录。
set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
将 OpenThread 添加到 build 树
如需在 build 树中添加 openthread 子模块，请执行以下操作：
add_subdirectory(openthread)
将 build 属性传递给 OpenThread
此文件的最后部分允许您定义可能需要添加到 openthread build 树和平台库的 build 属性（例如定义、选项和包含目录）。
添加这些定义的便捷方式是使用 ot-config 目标。此目标是一个伪造目标，仅用于定义配置，并且与 openthread 中的几乎所有 CMake 目标相关联。
# Define config filename macros
target_compile_definitions(ot-config INTERFACE
OPENTHREAD_CONFIG_FILE="openthread-core-efr32-config.h"
OPENTHREAD_PROJECT_CORE_CONFIG_FILE="openthread-core-efr32-config.h"
OPENTHREAD_CORE_CONFIG_PLATFORM_CHECK_FILE="openthread-core-efr32-config-check.h"
)
# Disable -Wshadow and -Wpedantic
target_compile_options(ot-config INTERFACE
-Wno-shadow
-Wno-pedantic
)
# Add platform dirs to "include" dirs
target_include_directories(ot-config INTERFACE
${PROJECT_SOURCE_DIR}/src/src
${PROJECT_SOURCE_DIR}/src/${EFR32_PLATFORM}
${PROJECT_SOURCE_DIR}/src/${EFR32_PLATFORM}/crypto
)
向 build 树添加子目录
现在，顶级配置已定义，是时候向 build 树添加其他子目录了。
src 文件夹是平台抽象层源代码所在的位置。third_party 文件夹包含所有第三方代码。
如果您想在代码库中添加示例应用，请创建一个 examples 文件夹，并将其添加到 build 树中。
add_subdirectory(src) add_subdirectory(third_party) # Optional add_subdirectory(examples)
src 目录
这是代码库的核心，也是实现平台抽象层的位置。它还包含一些其他必需的文件。
src/arm-none-eabi.cmake
这是一个工具链文件，用于定义 CMake 在构建过程中使用的一些变量。您不妨先复制此文件的 ot-efr32 版本，然后对其进行修改以适合您的平台。
src/CMakeLists.txt
您可以在其中定义平台库的源文件、包含路径和编译器标记。对于仅支持单一平台的代码库，ot-cc2538 就是一个很好的示例文件。
可以在单个代码库中支持多个平台，并且可以将多个平台代码库用作参考。请参阅 ot-efr32 和 ot-nrf528xx。