O sistema de build CMake depende de arquivos CMakeLists.txt, que definem destinos de build. O CMakeLists.txt na raiz do repositório fica no topo da árvore de build e é um bom lugar para começar a definir os vários destinos, opções e macros usados no processo de build.
Os primeiros valores a serem definidos são o nome do projeto e as plataformas compatíveis.
Neste exemplo, definimos o nome do projeto como ot-efr32 com uma versão de 0.0.1. Também definimos uma variável EFR32_PLATFORM_VALUES, que é uma lista de plataformas efr32 compatíveis com ot-efr32. Neste exemplo, definimos várias plataformas, mas também é bom ter uma única plataforma para a variável _PLATFORM_VALUES.
cmake_minimum_required(VERSION 3.10.2)
project(ot-efr32 VERSION 0.0.1)
set(EFR32_PLATFORM_VALUES
"efr32mg1"
"efr32mg12"
"efr32mg13"
"efr32mg21"
)
O arquivo CMakeLists.txt inclui uma verificação que cancela builds iniciados para plataformas sem suporte.
set_property(CACHE EFR32_PLATFORM PROPERTY STRINGS ${EFR32_PLATFORM_VALUES})
if(NOT EFR32_PLATFORM IN_LIST EFR32_PLATFORM_VALUES)
message(FATAL_ERROR "Please select a supported platform: ${EFR32_PLATFORM_VALUES}")
endif()
A próxima variável que precisa ser definida é OT_PLATFORM_LIB. Essa variável é usada pelos aplicativos de exemplo do OpenThread para vincular à sua plataforma.
set(OT_PLATFORM_LIB "openthread-${EFR32_PLATFORM}")
Opções do CMake do OpenThread
Vários recursos do OpenThread podem ser ativados/desativados/configurados definindo variáveis do CMake.
Na plataforma ot-efr32, uma biblioteca mbedTLS externa silabs-mbedtls é usada.
set(OT_BUILTIN_MBEDTLS_MANAGEMENT OFF CACHE BOOL "disable builtin mbedtls management" FORCE)
set(OT_EXTERNAL_MBEDTLS "silabs-mbedtls" CACHE STRING "use silabs mbedtls" FORCE)
set(OT_MBEDTLS ${OT_EXTERNAL_MBEDTLS})
Definir diretórios de saída
O diretório de saída para diferentes arquivos de destino pode ser configurado usando as variáveis abaixo.
set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
Adicionar o OpenThread à árvore de build
Para incluir o submódulo openthread na árvore de build:
add_subdirectory(openthread)
Transmitir propriedades do build para o OpenThread
A seção final desse arquivo permite definir propriedades de build (como definições, opções e diretórios de inclusão) que você pode querer adicionar à árvore de build openthread e às bibliotecas da sua plataforma.
Uma maneira conveniente de adicionar essas definições é usando o destino ot-config. Esse destino é falso, usado exclusivamente para definir a configuração, e é vinculado por quase todos os destinos do CMake em openthread.
# Define config filename macros
target_compile_definitions(ot-config INTERFACE
OPENTHREAD_CONFIG_FILE="openthread-core-efr32-config.h"
OPENTHREAD_PROJECT_CORE_CONFIG_FILE="openthread-core-efr32-config.h"
OPENTHREAD_CORE_CONFIG_PLATFORM_CHECK_FILE="openthread-core-efr32-config-check.h"
)
# Disable -Wshadow and -Wpedantic
target_compile_options(ot-config INTERFACE
-Wno-shadow
-Wno-pedantic
)
# Add platform dirs to "include" dirs
target_include_directories(ot-config INTERFACE
${PROJECT_SOURCE_DIR}/src/src
${PROJECT_SOURCE_DIR}/src/${EFR32_PLATFORM}
${PROJECT_SOURCE_DIR}/src/${EFR32_PLATFORM}/crypto
)
Adicionar subdiretórios à árvore de build
Agora que a configuração de nível superior foi definida, é hora de adicionar outros subdiretórios à árvore de build.
A pasta src é onde está o código-fonte da camada de abstração da plataforma. A pasta third_party contém códigos de terceiros.
Se você quiser incluir aplicativos de exemplo no repositório, crie uma pasta examples e a adicione à árvore de build também.
add_subdirectory(src) add_subdirectory(third_party) # Optional add_subdirectory(examples)
O diretório src
Esse é o coração do repositório e é onde a camada de abstração da plataforma é implementada. Ele também contém alguns outros arquivos necessários.
src/arm-none-eabi.cmake
Esse é um arquivo de conjunto de ferramentas que define algumas variáveis que o CMake usa no processo de compilação. Um bom ponto de partida é copiar a versão ot-efr32 desse arquivo e modificá-la de acordo com sua plataforma.
src/CMakeLists.txt
É aqui que você define os arquivos de origem, caminhos de inclusão e sinalizações do compilador para sua biblioteca de plataforma. Um bom exemplo desse arquivo para um repositório compatível com apenas uma plataforma é o ot-cc2538 (link em inglês).
É possível oferecer suporte a várias plataformas em um único repositório, e vários repositórios de plataformas podem ser usados como referência. Consulte ot-efr32 e ot-nrf528xx.