CMake-Regeln definieren

<ph type="x-smartling-placeholder"></ph> Quelle auf GitHub ansehen

Von <ph type="x-smartling-placeholder"></ph> <ph type="x-smartling-placeholder"></ph> Mason Tran

Beitragender von SiLabs

Das Build-System von CMake stützt sich auf CMakeLists.txt-Dateien, die Build-Ziele definieren. Die CMakeLists.txt im Stammverzeichnis Ihres Repositorys befindet sich oben in der Build-Struktur und ist ein guter Ausgangspunkt, um die verschiedenen Ziele, Optionen und Makros zu definieren, die im Build-Prozess verwendet werden.

Die allerersten Werte, die definiert werden müssen, sind der Projektname und die unterstützten Plattformen.

In diesem Beispiel haben wir den Projektnamen auf ot-efr32 mit der Version 0.0.1 festgelegt. Außerdem definieren wir die Variable EFR32_PLATFORM_VALUES, eine Liste der efr32-Plattformen, die von ot-efr32 unterstützt werden. Für dieses Beispiel haben wir mehrere Plattformen definiert, aber es ist auch in Ordnung, eine einzige Plattform für die Variable _PLATFORM_VALUES zu haben.

cmake_minimum_required(VERSION 3.10.2)
project(ot-efr32 VERSION 0.0.1)

set(EFR32_PLATFORM_VALUES
    "efr32mg1"
    "efr32mg12"
    "efr32mg13"
    "efr32mg21"
)

Die Datei CMakeLists.txt enthält eine Prüfung, durch die Builds abgebrochen werden, die für nicht unterstützte Plattformen gestartet wurden.

set_property(CACHE EFR32_PLATFORM PROPERTY STRINGS ${EFR32_PLATFORM_VALUES})
if(NOT EFR32_PLATFORM IN_LIST EFR32_PLATFORM_VALUES)
    message(FATAL_ERROR "Please select a supported platform: ${EFR32_PLATFORM_VALUES}")
endif()

Die nächste Variable, die definiert werden muss, ist OT_PLATFORM_LIB. Diese Variable wird von den OpenThread-Beispielanwendungen verwendet, um eine Verknüpfung zu Ihrer Plattform herzustellen.

set(OT_PLATFORM_LIB "openthread-${EFR32_PLATFORM}")

OpenThread-CMake-Optionen

Verschiedene Funktionen in OpenThread können durch die Definition von CMake-Variablen aktiviert/deaktiviert/konfiguriert werden.

Auf der Plattform ot-efr32 wird die externe mbedTLS-Bibliothek silabs-mbedtls verwendet.

set(OT_BUILTIN_MBEDTLS_MANAGEMENT OFF CACHE BOOL "disable builtin mbedtls management" FORCE)
set(OT_EXTERNAL_MBEDTLS "silabs-mbedtls" CACHE STRING "use silabs mbedtls" FORCE)
set(OT_MBEDTLS ${OT_EXTERNAL_MBEDTLS})

Ausgabeverzeichnisse definieren

Das Ausgabeverzeichnis für verschiedene Zieldateien kann mithilfe der folgenden Variablen konfiguriert werden.

set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)

OpenThread zur Build-Struktur hinzufügen

So fügen Sie das Untermodul openthread in den Build-Baum ein:

add_subdirectory(openthread)

Build-Attribute an OpenThread übergeben

Im letzten Abschnitt dieser Datei können Sie Build-Attribute wie Definitionen, Optionen und Verzeichnisse definieren, die Sie dem Build-Baum openthread und Ihren Plattformbibliotheken hinzufügen können.

Eine bequeme Möglichkeit, diese Definitionen hinzuzufügen, ist das Ziel ot-config. Dieses Ziel ist ein gefälschtes Ziel, das ausschließlich zur Definition der Konfiguration verwendet wird und mit dem von fast allen CMake-Zielen in openthread verknüpft wird.

# Define config filename macros
target_compile_definitions(ot-config INTERFACE
    OPENTHREAD_CONFIG_FILE="openthread-core-efr32-config.h"
    OPENTHREAD_PROJECT_CORE_CONFIG_FILE="openthread-core-efr32-config.h"
    OPENTHREAD_CORE_CONFIG_PLATFORM_CHECK_FILE="openthread-core-efr32-config-check.h"
)

# Disable -Wshadow and -Wpedantic
target_compile_options(ot-config INTERFACE
    -Wno-shadow
    -Wno-pedantic
)

# Add platform dirs to "include" dirs
target_include_directories(ot-config INTERFACE
    ${PROJECT_SOURCE_DIR}/src/src
    ${PROJECT_SOURCE_DIR}/src/${EFR32_PLATFORM}
    ${PROJECT_SOURCE_DIR}/src/${EFR32_PLATFORM}/crypto
)

Unterverzeichnisse zur Build-Struktur hinzufügen

Nachdem Sie die Konfiguration der obersten Ebene definiert haben, fügen Sie dem Build-Baum weitere Unterverzeichnisse hinzu.

Im Ordner src befindet sich der Quellcode der Plattformabstraktionsebene. Der Ordner third_party enthält Drittanbietercode.

Wenn Sie Beispielanwendungen in das Repository aufnehmen möchten, erstellen Sie den Ordner examples und fügen Sie ihn ebenfalls der Build-Struktur hinzu.

add_subdirectory(src)
add_subdirectory(third_party)

# Optional
add_subdirectory(examples)

Verzeichnis src

Dies ist das Herz des Repositorys, in dem die Plattformabstraktionsebene implementiert ist. Außerdem sind einige weitere erforderliche Dateien enthalten.

src/arm-none-eabi.cmake

Dies ist eine Toolchain-Datei, die einige Variablen definiert, die CMake im Build-Prozess verwendet. Ein guter Ausgangspunkt wäre, die ot-efr32-Version dieser Datei zu kopieren und an Ihre Plattform anzupassen.

src/CMakeLists.txt

Hier definieren Sie die Quelldateien sowie die Pfade und Compiler-Flags für Ihre Plattformbibliothek. Ein gutes Beispiel für diese Datei für ein Repository, das nur eine Plattform unterstützt, ist ot-cc2538.

Es werden mehrere Plattformen in einem einzelnen Repository unterstützt und mehrere Plattform-Repositories können als Referenz verwendet werden. Weitere Informationen finden Sie unter ot-efr32 und ot-nrf528xx.